Feat: Shift from Stable to Preview (WIP)

2026-06-13 01:09:56 -05:00 · 2026-04-30 01:04:56 -05:00
parent 4d3dfdbec6
commit 79cb2f7c56
43 changed files with 1140 additions and 956 deletions
@@ -0,0 +1,18 @@
+{ lib, stdenv, nodejs_22, pnpm, pnpmConfigHook, version, src }:
+
+stdenv.mkDerivation {
+  pname = "moku-frontend";
+  inherit version src;
+
+  nativeBuildInputs = [ nodejs_22 pnpm pnpmConfigHook ];
+
+  pnpmDeps = pnpm.fetchDeps {
+    pname = "moku-frontend";
+    inherit version src;
+    fetcherVersion = 1;
+    hash = "sha256-t6Gj84hCE3CuDAJfbdXi0FuqgPCqlkMmAzETcKL4e3U=";
+  };
+
+  buildPhase = "pnpm build";
+  installPhase = "cp -r dist $out";
+}
@@ -0,0 +1,73 @@
+{
+  lib,
+  craneLib,
+  pkgs,
+  runtimeLibs,
+  frontend,
+  suwayomiServer,
+  version,
+  cargoSrc,
+}:
+
+let
+  commonArgs = {
+    src = cargoSrc;
+    cargoToml = ./src-tauri/Cargo.toml;
+    cargoLock = ./src-tauri/Cargo.lock;
+    strictDeps = true;
+    buildInputs = runtimeLibs;
+    nativeBuildInputs = with pkgs; [ pkg-config wrapGAppsHook3 ];
+    preBuild = ''
+      cp -r ${frontend} ../dist
+    '';
+  };
+
+  cargoArtifacts = craneLib.buildDepsOnly commonArgs;
+in
+craneLib.buildPackage (commonArgs // {
+  inherit cargoArtifacts;
+
+  meta.mainProgram = "moku";
+
+  postInstall = ''
+    mkdir -p "$out/share/applications"
+    cat > "$out/share/applications/moku.desktop" << EOF
+[Desktop Entry]
+Version=1.0
+Type=Application
+Name=Moku
+Comment=Manga reader frontend for Suwayomi
+Exec=$out/bin/moku
+Icon=moku
+Terminal=false
+Categories=Graphics;Viewer;
+Keywords=manga;comic;reader;suwayomi;
+StartupWMClass=moku
+EOF
+
+    for size in 32x32 128x128 256x256 512x512; do
+      src="icons/$size.png"
+      [ -f "$src" ] && install -Dm644 "$src" \
+        "$out/share/icons/hicolor/$size/apps/moku.png"
+    done
+
+    for size in 128x128 256x256; do
+      src="icons/''${size}@2x.png"
+      [ -f "$src" ] && install -Dm644 "$src" \
+        "$out/share/icons/hicolor/''${size}@2/apps/moku.png"
+    done
+
+    install -Dm644 "${./src/assets/moku-icon.svg}" \
+      "$out/share/icons/hicolor/scalable/apps/moku.svg"
+
+    wrapProgram $out/bin/moku \
+      --prefix XDG_DATA_DIRS : "${lib.makeSearchPath "share/gsettings-schemas" [
+        pkgs.gsettings-desktop-schemas
+        pkgs.gtk3
+      ]}" \
+      --prefix LD_LIBRARY_PATH : "${lib.makeLibraryPath runtimeLibs}" \
+      --prefix PATH : "${lib.makeBinPath [ suwayomiServer ]}" \
+      --set GDK_BACKEND wayland \
+      --set WEBKIT_DISABLE_SANDBOX_THIS_IS_DANGEROUS 1
+  '';
+})
@@ -0,0 +1,133 @@
+{ pkgs, rustToolchain, version }:
+
+{
+  bump = pkgs.writeShellApplication {
+    name = "moku-bump";
+    runtimeInputs = with pkgs; [
+      gnused
+      coreutils
+      git
+      rustToolchain
+      nodejs_22
+      pnpm
+      (python3.withPackages (ps: [ ps.aiohttp ps.tomlkit ]))
+    ];
+    text = ''
+      [[ $# -lt 1 ]] && { echo "Usage: nix run .#bump -- <version>"; exit 1; }
+      VERSION="$1"
+      REPO="$(git rev-parse --show-toplevel)"
+
+      echo "── Bumping version fields to $VERSION ──"
+      sed -i "s/\"version\": \"[^\"]*\"/\"version\": \"$VERSION\"/" \
+        "$REPO/src-tauri/tauri.conf.json"
+      sed -i "0,/^version = \"[^\"]*\"/s//version = \"$VERSION\"/" \
+        "$REPO/src-tauri/Cargo.toml"
+      sed -i "s/version = \"[^\"]*\";/version = \"$VERSION\";/g" \
+        "$REPO/flake.nix"
+      sed -i "s/^pkgver=.*/pkgver=$VERSION/" "$REPO/PKGBUILD"
+      sed -i "s/^pkgrel=.*/pkgrel=1/"        "$REPO/PKGBUILD"
+      echo "Done"
+
+      echo "── Regenerating Cargo.lock ──"
+      (cd "$REPO/src-tauri" && cargo generate-lockfile)
+      echo "Done"
+
+      echo "── Building frontend ──"
+      cd "$REPO"
+      pnpm install --frozen-lockfile
+      pnpm build
+      echo "Done"
+
+      echo "── Repacking frontend-dist.tar.gz ──"
+      tar -czf "$REPO/packaging/frontend-dist.tar.gz" -C "$REPO" dist
+      FRONTEND_SHA=$(sha256sum "$REPO/packaging/frontend-dist.tar.gz" | awk '{print $1}')
+      echo "sha256: $FRONTEND_SHA"
+
+      echo "── Regenerating cargo-sources.json ──"
+      python3 "$REPO/packaging/flatpak-cargo-generator.py" \
+        "$REPO/src-tauri/Cargo.lock" \
+        -o "$REPO/packaging/cargo-sources.json"
+      echo "Done"
+
+      echo "── Patching flatpak manifest ──"
+      MANIFEST="$REPO/io.github.moku_project.Moku.yml"
+      sed -i "s/tag: v[^[:space:]]*/tag: v$VERSION/" "$MANIFEST"
+      python3 - "$MANIFEST" "$FRONTEND_SHA" <<'PYEOF'
+      import re, sys
+      path, sha = sys.argv[1], sys.argv[2]
+      text = open(path).read()
+      updated, n = re.subn(
+        r'(path:\s*packaging/frontend-dist\.tar\.gz\s*\n\s*sha256:\s*)[0-9a-f]+',
+        r'\g<1>' + sha, text)
+      if n == 0:
+          sys.exit("ERROR: could not find frontend-dist sha256 in manifest")
+      open(path, 'w').write(updated)
+      PYEOF
+      echo "Done"
+
+      echo ""
+      echo "Bumped to v$VERSION — commit, tag, push, then: nix run .#post-tag-bump -- $VERSION"
+    '';
+  };
+
+  postTagBump = pkgs.writeShellApplication {
+    name = "moku-post-tag-bump";
+    runtimeInputs = with pkgs; [ gnused coreutils git curl ];
+    text = ''
+      [[ $# -lt 1 ]] && { echo "Usage: nix run .#post-tag-bump -- <version>"; exit 1; }
+      VERSION="$1"
+      REPO="$(git rev-parse --show-toplevel)"
+      MANIFEST="$REPO/io.github.moku_project.Moku.yml"
+      PKGBUILD="$REPO/PKGBUILD"
+
+      echo "── Resolving commit for v$VERSION ──"
+      COMMIT=$(git ls-remote https://github.com/moku-project/Moku.git "refs/tags/v$VERSION" \
+        | awk '{print $1}')
+      [[ -z "$COMMIT" ]] && { echo "ERROR: tag v$VERSION not found on remote"; exit 1; }
+      echo "commit: $COMMIT"
+      sed -i "s/commit: [0-9a-f]\{40\}/commit: $COMMIT/" "$MANIFEST"
+      echo "Done"
+
+      echo "── Fetching PKGBUILD tarball sha256 ──"
+      TARBALL_URL="https://github.com/moku-project/Moku/archive/refs/tags/v$VERSION.tar.gz"
+      TARBALL_SHA=$(curl -fsSL "$TARBALL_URL" | sha256sum | awk '{print $1}')
+      sed -i "/sha256sums=/,/)/{ 0,/'/s/'[^']*'/'$TARBALL_SHA'/ }" "$PKGBUILD"
+      grep -q "$TARBALL_SHA" "$PKGBUILD" \
+        || { echo "ERROR: PKGBUILD sha256 replacement failed"; exit 1; }
+      echo "Done"
+
+      echo ""
+      echo "post-tag-bump complete for v$VERSION"
+    '';
+  };
+
+  flatpak = pkgs.writeShellApplication {
+    name = "moku-flatpak";
+    runtimeInputs = with pkgs; [ coreutils git appstream flatpak-builder flatpak ];
+    text = ''
+      [[ $# -lt 1 ]] && { echo "Usage: nix run .#flatpak -- <version>"; exit 1; }
+      REPO="$(git rev-parse --show-toplevel)"
+      MANIFEST="$REPO/io.github.moku_project.Moku.yml"
+
+      rm -rf "$REPO/build-dir" "$REPO/repo"
+      flatpak-builder \
+        --repo="$REPO/repo" \
+        --force-clean \
+        "$REPO/build-dir" \
+        "$MANIFEST"
+      flatpak build-bundle "$REPO/repo" "$REPO/moku.flatpak" io.github.moku_project.Moku
+      rm -rf "$REPO/build-dir" "$REPO/repo"
+
+      echo "moku.flatpak created"
+    '';
+  };
+
+  tunnel = pkgs.writeShellApplication {
+    name = "moku-tunnel";
+    runtimeInputs = with pkgs; [ cloudflared ];
+    text = ''
+      PORT="''${1:-4567}"
+      cloudflared tunnel --url "http://localhost:$PORT"
+    '';
+  };
+}
@@ -0,0 +1,46 @@
+{
+  lib,
+  stdenvNoCC,
+  fetchurl,
+  makeWrapper,
+  jdk21_headless,
+}:
+let
+  jdk = jdk21_headless;
+in
+stdenvNoCC.mkDerivation (finalAttrs: {
+  pname = "suwayomi-server";
+  version = "2.1.2087";
+
+  src = fetchurl {
+    url = "https://github.com/Suwayomi/Suwayomi-Server-preview/releases/download/v${finalAttrs.version}/Suwayomi-Server-v${finalAttrs.version}.jar";
+    hash = "sha256-9YmkImdCUjlME7KJqci+aRkFv1g++39NXxUBrl6R5rM=";
+  };
+
+  nativeBuildInputs = [ makeWrapper ];
+
+  dontUnpack = true;
+
+  buildPhase = ''
+    runHook preBuild
+
+    install -Dm644 $src $out/share/suwayomi-server/suwayomi-server.jar
+
+    makeWrapper ${jdk}/bin/java $out/bin/suwayomi-server \
+      --add-flags "-Dsuwayomi.tachidesk.config.server.initialOpenInBrowserEnabled=false" \
+      --add-flags "-jar $out/share/suwayomi-server/suwayomi-server.jar"
+
+    runHook postBuild
+  '';
+
+  meta = {
+    description = "Free and open source manga reader server that runs extensions built for Mihon (Tachiyomi)";
+    homepage = "https://github.com/Suwayomi/Suwayomi-Server";
+    downloadPage = "https://github.com/Suwayomi/Suwayomi-Server-preview/releases";
+    changelog = "https://github.com/Suwayomi/Suwayomi-Server-preview/releases/tag/v${finalAttrs.version}";
+    license = lib.licenses.mpl20;
+    platforms = jdk.meta.platforms;
+    sourceProvenance = [ lib.sourceTypes.binaryBytecode ];
+    mainProgram = "suwayomi-server";
+  };
+})